Простая, казалось бы, задача - сделать средствами СКД отчет с двумя колонками: "Номенклатура" и ее "Изображение". Давайте попробуем это реализовать.

Создадим новый отчет.

Набор данных типа запрос. 

Сделаем настройки схемы компоновки. 

Отчет будет выглядить вот так. 

Как же теперь вывести картинки? Алгоритм примерно следующий. Перехватим обработчки ПриКомпоновкеРезультата(), последовательно пробежимся по всем ячейкам табличного документа и выведем вместо ХранилицеЗначения соответствующую картинку. 

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

    СтандартнаяОбработка = Ложь;

    НастройкиКомпоновки = КомпоновщикНастроек.ПолучитьНастройки();

    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки);

    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);

    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);


    Для ТекущаяСтрока = 1 По ДокументРезультат.ВысотаТаблицы Цикл

        Для ТекущаяКолонка = 1 По ДокументРезультат.ШиринаТаблицы Цикл

            ТекущаяОбласть = ДокументРезультат.Область(ТекущаяСтрока, ТекущаяКолонка);
            ТекущаяРасшифровка = ТекущаяОбласть.Расшифровка;

            Если ТипЗнч(ТекущаяРасшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда

                ПоляРасшифровки = ДанныеРасшифровки.Элементы.Получить(ТекущаяРасшифровка).ПолучитьПоля();
                ПолеКартинки = ПоляРасшифровки.Найти("Картинка");

                Если ТипЗнч(ПолеКартинки) = Тип("ЗначениеПоляРасшифровкиКомпоновкиДанных") Тогда

                    ФайлКартинки = ПолеКартинки.Значение;

                    Если ТипЗнч(ФайлКартинки) = Тип("ХранилищеЗначения") Тогда

                        КартинкаВДокументе = ДокументРезультат.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка);
                        КартинкаВДокументе.Картинка = Новый Картинка(ФайлКартинки.Получить());
                        КартинкаВДокументе.РазмерКартинки = РазмерКартинки.Пропорционально;
                        КартинкаВДокументе.Расположить(ТекущаяОбласть);

                    КонецЕсли;

                КонецЕсли;

            КонецЕсли;

        КонецЦикла;

    КонецЦикла;

КонецПроцедуры

 

Теперь отчет формируется вот так. Задача решена.